1.4. Mapas Físico - Político. Sudamérica.

Mapa físico-político con proyección cónica (Albers) de sudamérica.

Este ejemplo muestra como elaborar un mapa con proyección cónica (Albers). Además incluye como agregar divisiones políticas deestados/provincias de (nivel 2) y ríos con distintos estilos de líneas (punteadas, segmentas, etc.).

Datos:

• Global Self-consistent, Hierarchical, High-resolution Geography Database (GSHHG; incluido en GMT, Link): Conjunto de datos de líneas de costa de alta resolución.
• Digital Chart of the World (DCW): Base de datos vectorial de los países del mundo y de las provincias/estados de los 8 más grande (en superficie, incluye Argentina).

Script

Variables del Mapas:

1.  Región: Se define la región geográfica que incluya Sudamérica.

REM    Titulo del mapa
    SET    title=TP1.4_MapaPolitico_Sudamerica
    echo %title%

REM    Region: Sudamérica
    SET    REGION=-85/-33/-58/15


2. Proyección: Con la letra B-60/-30/-40/0 se selecciona la proyección cónica de Albers centrado en 60 °O y 30 °S y con paralelos tangentes a 40 °S y 0 ° (Ecuador). El ancho de la figura es de 15 cm.

Nota: Las proyecciones cónicas requieren que se indiquen 4 parámetros: El centro del mapa (long0/lat0) y 2 paralelos (lat1 y lat2) donde el cono es tangente a la superficie de la tierra.

REM    Proyeccion Conica. (lon0/lat0/lat1/lat2/width) Proyeccion Albers (B); Lambert (L): Equidistant (D).
    SET    PROJ=B-60/-30/-40/0/15c

REM     Nombre archivo de salida
    SET    OUT=%title%.ps

Dibujar el mapa:

3. Comandos previos: Se utilizan comandos descriptos en los ejemplos anteriores: Abrir archivo de salida, límites de países, líneas de costas, pintar a Argentina, marco del mapa.

REM    Abrir archivo de salida (ps)
    gmt psxy -R%REGION% -J%PROJ% -T -K -P > %OUT%

REM    Resaltar paises DCW (AR: Argentina soberana, FK: Malvinas, GS: Georgias del Sur y Sandwich del Sur)
    gmt pscoast -R -J -O -K >> %OUT% -EAR,FK,GS+grosybrown2+p

REM    Dibujar Bordes Administrativos. N1: paises. N2: Provincias, Estados, etc. N3: limites marítimos (Nborder[/pen])
    gmt pscoast -R -J -O -K -Df >> %OUT% -N1/0.75

REM    Dibujar Linea de Costa (level/, where level is 1-4 and represent coastline, lakeshore, island-in-lake shore, and lake-in-island-in-lake shore)
    gmt pscoast -R -J -O -K -Df >> %OUT% -W1/0.25

4. Marco del mapa: Con psbasemap -B se dibuja un marco del mapa con las siguientes opciones:

• f: marco con alternancia de segmentos blancos y negros.
  
• a: anotaciones de las coordenadas.

Nota: Si no se indica ningún valor, entonces los intervalos son definidos automáticamente.

REM    Dibujar frame
    gmt psbasemap -R -J -O -K >> %OUT% -Baf

5. Provincias/Estados: Con pscoast -N se agregan las divisiones administrativas de nivel 2 con las siguientes opciones:

• -N2/0.25,-.: los límites se dibujan con una línea de 0.25 puntos tipográficos de ancho conformada por puntos y segmentos (-.). El color es negro por defecto.

REM    Dibujar Bordes Administrativos. N1: paises. N2: Provincias, Estados, etc. N3: limites marítimos (Nborder[/pen])
    gmt pscoast -R -J -O -K -Df -N1/0.75 >> %OUT%
    gmt pscoast -R -J -O -K -Df -N2/0.25,-. >> %OUT%

6. Océanos y lagos: Con pscoast se puede pintar los océanos (-S) y los lagos y ríos-lagos (-C). En cambio, para los lagos se define la variable "color" (que luego se utilzará también para los ríos) indicando los valores R/G/B (117/197/240)

• -Sdodgerblu2: Pintar océanos con ese color.
• -C%color%: Pintar (el área) de lagos y ríos-lagos.
  

rem    Pintar areas húmedas: Oceanos (-S) y Lagos y rios dobles
    Set color=117/197/240
    gmt pscoast -R -J -O -K -D%D% >> %OUT% -Sdodgerblue2 -C%color%

7. Ríos: Con pscoast -I se agregan los ríos disponibles en la base de GSHHG.

Nota: Para Sudamérica hay datos de 5 tipos de ríos:

• Nivel 0: ríos-lagos (doble línea)
• Nivel 1: mayores permanentes
• Nivel 2: mayores adicionales
• Nivel 3: adicionales
  
• Nivel 4: menores

Nota 2: En GMT las líneas (pen) se definen por 3 parámetros: ancho, color y estilo.

1. Ancho: Valor en puntos (p), pulgadas (i) o cm (c). Adicionalmetne existen 12 nombres con anchos predefinidos como por ejemplo: thin (0.75p), thinner (0.5p) y thinnest (0.25p).
   
2. Color: utilizamos la variable %color% definida previamente.
   
3. Estilos:, vamos a utilizar líneas sólidas (valor por default) para los niveles de rios 0 y 1; líneas segmentadas (-) para los niveles 2; líneas conformadas por 1 segmento y 3 puntos (-...) para los ríos 3. Para los ríos de nivel 4 definimos un estilo personalizado conformado por la alternancia de 4 puntos y un espacio de 1 punto y sin desfasaje (4_1:0p).

rem    Dibujar rios -Iriver[/pen] 
rem    0 = Double-lined rivers (river-lakes)
rem    1 = Permanent major rivers
rem    2 = Additional major rivers
rem    3 = Additional rivers
rem    4 = Minor rivers
    gmt pscoast -R -J -K -O -Df -I0/thin,%color% >> %OUT%   
    gmt pscoast -R -J -K -O -Df -I1/thinner,%color% >> %OUT%
    gmt pscoast -R -J -K -O -Df -I2/thinner,%color%,- >> %OUT%
    gmt pscoast -R -J -K -O -Df -I3/thinnest,%color%,-... >> %OUT%
    gmt pscoast -R -J -K -O -Df -I4/thinnest,%color%,4_1:0p >> %OUT% 

Actualización: 31-10-2016
8. Otras proyecciones: Se pueden crear mapas con otras proyecciones simplemente cambiando la letra que la define (punto 2). Por ejemplo, para rehacerlo con la proyección Lambert Cónica (L) se utiliza el siguiente comando: 

    SET    PROJ=L-60/-30/-40/0/15c 

Proyección Lambert (L)

Proyección Equidistante (D)